home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus Leser 15 / Amiga Plus Leser CD 15.iso / Scene / Eurochart44 / Bonus / tiny.s < prev   
Text File  |  2002-03-12  |  1KB  |  78 lines
  1. ;APS0000011F0000011F0000057E0000029F0000011F0000011F0000011F0000011F0000011F0000011F
  2.  
  3. ;   "Tiny" - a 256-byte starfield intro by Dr. Doom / IRIS
  4. ;   coded 26/07/2001
  5.  
  6.         section    code,code_c
  7. start        nop                    ; 256 bytes is too
  8.         nop                    ; much, zeeball!
  9.         nop
  10.         nop
  11.         nop
  12.         nop
  13.         move.l    4.w,a6
  14.         moveq    #10240>>8,d0
  15.         lsl.l    #8,d0
  16.         moveq    #3,d1
  17.         jsr    -198(a6)
  18.         move.l    d0,a2
  19. .loop        move.l    4(a6),a6
  20.         move.l    10(a6),a0
  21.         move.l    (a0)+,d0
  22.         add.l    (a0)+,d0
  23.         add.l    (a0),d0
  24.         cmp.l    #"grap"+"hics"+".lib",d0
  25.         bne.b    .loop
  26.         lea    $dff000,a5
  27.         move.l  $22(a6),d4
  28.         sub.l    a1,a1
  29.         jsr    -222(a6)
  30.         lea    copper(pc),a0
  31.         move.l    a0,$080(a5)
  32.         moveq.l    #-79,d0
  33.         lea    8192(a2),a0
  34.         move.w    #128*3-1,d7
  35. .initloop    ror.l    d0,d0
  36.         addq.l    #7,d0
  37.         move.w    d0,(a0)+
  38.         dbra    d7,.initloop        
  39. .mainloop    cmp.w    #$12f,5(a5)
  40.         bne.b    .mainloop
  41.         move.l    a2,$e0(a5)
  42.         move.l    a2,a0
  43.         move.w    #8192/4-1,d7
  44. .clearloop    clr.l    (a0)+
  45.         dbra    d7,.clearloop
  46.         moveq    #128-1,d6
  47. .loopstar    movem.w    (a0)+,d0-d2    
  48.         subq.b    #7,-2(a0)
  49.         bcs.b    .skipstar
  50.         lsr.w    #7,d2
  51.         divs.w    d2,d0
  52.         divs.w    d2,d1
  53.         add.w    #160,d0
  54.         cmp.w    #320,d0
  55.         bhs.b    .skipstar
  56.         add.w    #100,d1
  57.         cmp.w    #200,d1
  58.         bhs.b    .skipstar
  59.         muls.w    #40,d1
  60.         moveq    #-$80,d2
  61.         ror.b    d0,d2
  62.         lsr.w    #3,d0
  63.         add.w    d0,d1
  64.         or.b    d2,(a2,d1.w)
  65. .skipstar    dbra    d6,.loopstar
  66.         btst.b    #2,$016(a5)
  67.         bne.b    .mainloop
  68.         move.l  d4,a1
  69.         jsr    -222(a6)
  70.         move.l    $26(a6),$080(a5)
  71.         rts
  72. copper        dc.w    $0100,$1200
  73.         dc.w    $0180,$0424
  74.         dc.w    $0182,$008f
  75.         dc.w    $0096,$0020
  76.         dc.l    -2
  77.  
  78.